一键重置mysql的root密码脚本-mysql教程-PHP中文网

一键重置mysql的root密码脚本

php中文网

发布： 2016-06-07 16:29:05

原创

1330人浏览过

@echo off title mysql ::从注册表找到Mysql的安装路径写入文件mysql.txt reg query HKLM\SYSTEM\ControlSet001\Services\MySQL | find /I "ImagePath"C:\mysql.txt if %errorlevel% neq 0 ( echo MySQL not found pause exit ) ::以”为分隔符，截取第二段

 @echo off 

title mysql 

::从注册表找到Mysql的安装路径写入文件mysql.txt 
reg query HKLM\SYSTEM\ControlSet001\Services\MySQL | find /I "ImagePath">C:\mysql.txt 
if %errorlevel% neq 0 ( 
echo MySQL not found 
pause 
exit 
) 

::以”为分隔符，截取第二段内容保存到变量mysqlPath 
FOR /F tokens^=2^ delims^=^" %%i in (C:\mysql.txt) do set mysqlPath=%%i 
del C:\mysql.txt /f 

::路径中/替换为\ 
set mysqlPath=%mysqlPath:/=\% 

::删除路径最后一个字符（该字符不可见，可能是回车换行之类的） 
set mysqlPath=%mysqlPath:~0,-1% 

:BACKTOMAIN 

::取得路径最后一个字符看等不等于\ 
set character=%mysqlPath:~-1,1% 

::如果最后一个字符不等于\，那么跳转到GETPATH删除mysqlPath的最后一个字符 
if not %character% == \ goto GETPATH 

::进入mysql安装路径C:\Program Files\MySQL\MySQL Server 5.0\bin 
cd /d "%mysqlPath%" 

::echo %mysqlPath% 

if %errorlevel% neq 0 ( 
echo MySQL not found 
pause 
exit 
) 

::禁用mysql服务，跳过权限验证修改密码 
taskkill /F /IM mysqld-nt.exe 
net stop mysql >nul 
start /b mysqld-nt --skip-grant-tables 
ping -n 2 127.0.0.1 >nul 
echo use mysql >c:\config.tmp 
echo update user set password=password("") where user="root";>>C:\config.tmp 
echo flush privileges; >>C:\config.tmp 
echo exit >>C:\config.tmp 

::因为是交互式，所以从文件读取内容 
mysql <C:\config.tmp 
taskkill /F /IM mysqld-nt.exe 
net stop mysql >nul 
net start mysql 
del C:\config.tmp /F 
pause 
exit 

::删除路径最后一个字符，跳回主程序 
:GETPATH 
set mysqlPath=%mysqlPath:~0,-1% 
goto BACKTOMAIN

登录后复制

如果是用wamp一键安装需要改一些脚本，主要是注册表搜索路径改变，返回值改变，服务名改变了，mysql安装路径变成d:\wamp\bin\mysql\mysql5.5.24\bin，少了mysqld-nt这个东西，进程里面也没有mysqld-nt.exe

ECTouch移动商城系统

ECTouch是上海商创网络科技有限公司推出的一套基于 PHP 和 MySQL 数据库构建的开源且易于使用的移动商城网店系统！应用于各种服务器平台的高效、快速和易于管理的网店解决方案，采用稳定的MVC框架开发，完美对接ecshop系统与模板堂众多模板，为中小企业提供最佳的移动电商解决方案。ECTouch程序源代码完全无加密。安装时只需将已集成的文件夹放进指定位置，通过浏览器访问一键安装，无需对已有

查看详情

@echo off 

title mysql 

reg query HKLM\SYSTEM\ControlSet001\Services\wampmysqld | find /I "ImagePath">C:\mysql.txt 

if %errorlevel% neq 0 ( 
echo MySQL not found 
pause 
exit 
) 

FOR /F "tokens=3 delims= " %%i in (C:\mysql.txt) do set mysqlPath=%%i 
del C:\mysql.txt /f 
set mysqlPath=%mysqlPath:/=\% 
set mysqlPath=%mysqlPath:~0,-1% 

:BACKTOMAIN 
set character=%mysqlPath:~-1,1% 
if not %character% == \ goto GETPATH 
cd /d "%mysqlPath%" 

::echo %mysqlPath% 

if %errorlevel% neq 0 ( 
echo MySQL not found 
pause 
exit 
) 

taskkill /F /IM mysqld.exe 
net stop wampmysqld >nul 
start /b mysqld -nt --skip-grant-tables 
ping -n 2 127.0.0.1 >nul 
echo use mysql >c:\config.tmp 
echo update user set password=password("") where user="root";>>C:\config.tmp 
echo flush privileges; >>C:\config.tmp 
echo exit >>C:\config.tmp 

mysql <C:\config.tmp 

taskkill /F /IM mysqld.exe 
net stop wampmysqld >nul 
net start wampmysqld 
del C:\config.tmp /F 

pause 
exit 

:GETPATH 
set mysqlPath=%mysqlPath:~0,-1% 
goto BACKTOMAIN

登录后复制